**3.20. Заполнение объектов**

Подсистема «Заполнение объектов» предназначена для вывода команд заполнения в карточках, списках и журналах объектов программы.

Список команд определяется в составе конфигурации и автоматически выводится в подменю. Также имеется возможность переопределять список команд (добавлять новые команды и изменять существующие) при помощи расширений.

**Настройка**

Необходимо принять решение, для каких объектов программы и в каких их формах требуется выводить команды заполнения.

При этом стоит учитывать сценарии подключения команд при помощи расширений. Т. е. если для объекта программы не планируется поставлять команды заполнения в составе конфигурации, но есть вероятность, что партнеры захотят подключать к этому объекту свои команды заполнения (при помощи расширений), то рекомендуется подключить команды заполнения для этого объекта.

**Подключить объекты программы**

Объекты метаданных, для которых требуется выводить команды заполнения, следует перечислить в процедуре ПриОпределенииОбъектовСКомандамиЗаполнения модуля ЗаполнениеОбъектовПереопределяемый.

В модуле менеджера каждого объекта, подключенного к подсистеме «Заполнение объектов», в области программного интерфейса должна быть определена процедура ДобавитьКомандыЗаполнения по шаблону:

#Область ПрограммныйИнтерфейс

// Определяет список команд заполнения.

//

// Параметры:

//   КомандыЗаполнения - ТаблицаЗначений - Таблица с командами заполнения. Для изменения.

//       См. описание 1 параметра процедуры ЗаполнениеОбъектовПереопределяемый.ПередДобавлениемКомандЗаполнения().

//   Параметры - Структура - Вспомогательные параметры. Для чтения.

//       См. описание 2 параметра процедуры ЗаполнениеОбъектовПереопределяемый.ПередДобавлениемКомандЗаполнения().

//

Процедура ДобавитьКомандыЗаполнения(КомандыЗаполнения, Параметры) Экспорт

КонецПроцедуры

#КонецОбласти

**Подключить формы объектов программы**

В формах объектов, подключенных на предыдущем шаге, в которых требуется выводить подменю с командами заполнения, надо:

● Встроить подсистему "[Подключаемые команды](https://its.1c.ru/db/content/bsp301doc/src/3.39.%20подключаемые%20команды.htm?_=1542292879#_поиск_и_удаление)".

● Опционально. В командную панель добавить основное подменю для вывода команд заполнения по шаблону:

● Имя: "ПодменюЗаполнить",

● Заголовок: "Заполнить",

● Вид: Подменю,

● Отображение: Картинка,

● Картинка: ЗаполнитьФорму (картинка из конфигурации).

Если предполагается что в этом подменю может быть выведено большое количество команд (более 10), то рекомендуется добавить вложенные группы кнопок с суффиксами "Важное", "Обычное" и "СмТакже". Например: "ПодменюЗаполнитьВажное", "ПодменюЗаполнитьОбычное" и "ПодменюЗаполнитьСмТакже". Имена этих групп указываются в свойстве Важность тех команд, которые должны выводиться в этих группах. Подробнее про это свойство см. описание соответствующей колонки таблицы "КомандыЗаполнения".

● Помимо основного подменю в форме могут быть размещены дополнительные подменю (например - для заполнения табличных частей). Имена этих подменю указываются в свойстве Группа тех команд, которые должны выводиться в этих подменю. Имена подменю заполнения табличных частей рекомендуется образовывать путем добавления префикса с именем табличной части, например: "ТоварыПодменюЗаполнить".

**Настройка прав доступа пользователей**

Для настройки прав доступа дополнительных действий не требуется.

Таблица 3.38.

| № | Роли и их назначение |
| --- | --- |
| 1. | БазовыеПраваБСП или БазовыеПраваВнешнихПользователейБСП  Просмотр информации |

**Использование при разработке конфигурации**

**Разработка команд заполнения**

Команды заполнения объекта описываются в процедуре ДобавитьКомандыЗаполнения модуля менеджера этого объекта, например:

// Определяет список команд заполнения.

//

// Параметры:

//   КомандыЗаполнения - ТаблицаЗначений - Таблица с командами заполнения. Для изменения.

//       См. описание 1 параметра процедуры ЗаполнениеОбъектовПереопределяемый.ПередДобавлениемКомандЗаполнения().

//   Параметры - Структура - Вспомогательные параметры. Для чтения.

//       См. описание 2 параметра процедуры ЗаполнениеОбъектовПереопределяемый.ПередДобавлениемКомандЗаполнения().

//

Процедура ДобавитьКомандыЗаполнения(КомандыЗаполнения, Параметры) Экспорт

Команда = КомандыЗаполнения.Добавить();

...

КонецПроцедуры

Команды заполнения, используемые сразу во всех (или во многих) объектах метаданных, описываются в процедуре ПередДобавлениемКомандЗаполнения модуля ЗаполнениеОбъектовПереопределяемый, например:

Процедура ПередДобавлениемКомандЗаполнения(КомандыЗаполнения, НастройкиОбъекта, СтандартнаяОбработка) Экспорт

...

// Универсальная команда заполнения для справочников.

Если Метаданные.Справочники.Содержит(НастройкиОбъекта.Метаданные) Тогда

Команда = КомандыЗаполнения.Добавить();

...

КонецЕсли;

...

КонецПроцедуры

Также команды заполнения могут описываться в обработках конфигурации и расширений. Для этого обработка должна входить в состав подсистемы ПодключаемыеОтчетыИОбработки и в ее модуле менеджера в области ПрограммныйИнтерфейс должна быть определена процедура ПриОпределенииНастроек по шаблону [подключения отчетов и обработок к другим объектам метаданных](https://its.1c.ru/db/content/bsp301doc/src/3.4.%20базовая%20функциональность.htm?_=1542292879#_подключение_отчетов_и), а также процедура ДобавитьКомандыЗаполнения. Например:

#Область ПрограммныйИнтерфейс

// Определяет состав программного интерфейса для интеграции с конфигурацией.

//

// Параметры:

//   Настройки - Структура - Настройки интеграции этого объекта.

//       См. возвращаемое значение функции ПодключаемыеКоманды.НастройкиПодключаемыхОтчетовИОбработок().

//

Процедура ПриОпределенииНастроек(Настройки) Экспорт

Настройки.Размещение.Добавить(Метаданные.Документы.ИмяДокумента);

Настройки.ДобавитьКомандыЗаполнения = Истина;

КонецПроцедуры

// Определяет список команд заполнения.

//

// Параметры:

//   КомандыЗаполнения - ТаблицаЗначений - Таблица с командами заполнения. Для изменения.

//       См. описание 1 параметра процедуры ЗаполнениеОбъектовПереопределяемый.ПередДобавлениемКомандЗаполнения().

//   Параметры - Структура - Вспомогательные параметры. Для чтения.

//       См. описание 2 параметра процедуры ЗаполнениеОбъектовПереопределяемый.ПередДобавлениемКомандЗаполнения().

//

Процедура ДобавитьКомандыЗаполнения(КомандыЗаполнения, Параметры) Экспорт

Команда = КомандыЗаполнения.Добавить();

...

КонецПроцедуры

#КонецОбласти

Описание команд заполнения в обработках конфигурации рекомендуется использовать для команд, обслуживающих сразу несколько объектов (список обслуживаемых объектов является группирующим признаком для таких команд).

Процедура ДобавитьКомандыЗаполнения обработок, подключенных по такой технологии, вызывается для всех объектов метаданных, указанных в параметре Размещение процедуры ПриОпределенииНастроек.

Таблица 3.39. Колонки таблицы «КомандыЗаполнения»

| Параметр | Тип | Описание |
| --- | --- | --- |
| Идентификатор (необязательный) | Строка | Идентификатор команды, который используется для идентификации команды и определения имени команды в форме.  Если идентификатор не указан, то имя команды будет определено автоматически |
| Представление (обязательный) | Строка | Представление команды в форме. Пример:  Команда.Представление = НСтр("ru = 'Заполнить ТТН'"); |
| Важность (необязательный) | Строка | Краткое имя (суффикс) группы в подменю, в которой следует вывести эту команду. Допустимо использовать: "Важное", "Обычное" и "СмТакже". |
| Порядок  (необязательный) | Число | Значение от 1 до 100, указывающее порядок размещения команды по отношению к другим командам. Сортировка команд осуществляется сначала по полю Порядок, затем по представлению.  Значение по умолчанию: 50 |
| СочетаниеКлавиш (необязательный) | СочетаниеКлавиш | Сочетание клавиш для быстрого вызова команды |
| Настройки видимости и доступности: | | |
| ТипПараметра (необязательный) | ОписаниеТипов | Типы объектов, для которых предназначена эта команда. Используется, когда обработка (или другой поставщик команд) подключена к нескольким объектам конфигурации, для уточнения списка объектов, к которым подключена конкретная команда |
| ВидимостьВФормах (необязательный) | Строка | Имена форм, в которых должна отображаться команда, через запятую. Используется для уточнения состава форм, к которым подключена конкретная команда. Если параметр не указан, то команда будет отображаться во всех формах. Пример:  Команда.ВидимостьВФормах = "ФормаДокумента" |
| ФункциональныеОпции  (необязательный) | Строка | Имена функциональных опций, определяющих видимость команды, через запятую. |
| УсловияВидимости (необязательный) | Массив | Определяет видимость команды в зависимости от контекста.  Для регистрации условий следует использовать процедуру Подключае-мыеКоманды.ДобавитьУсловиеВидимостиКоманды().  Условия объединяются по "И". |
| ИзменяетВыбранныеОбъекты (необязательный) | Булево | Определяет доступность команды в ситуации, когда у пользователя нет прав на изменение объекта. Если Истина, то кнопка будет недоступна. Значение по умолчанию: Ложь. |
| Настройки процесса выполнения: | | |
| МножественныйВыбор (необязательный) | Булево | Если Истина, то команда поддерживает множественный выбор и в 1 параметре обработчика команды будет передан массив ссылок.  Если Ложь, то команда поддерживает только одиночный выбор и в 1 параметре обработчика команды будет передана 1 ссылка |
| РежимЗаписи (необязательный) | Строка | Настройки дополнительных проверок и действий, связанных к записью объекта, выполняемых перед обработчиком команды:  ● НеЗаписывать – объект не записывается, а в параметрах обработчика вместо ссылок передается вся форма. В этом режиме рекомендуется работать напрямую с формой, которая передается в структуре 2 параметра обработчика команды.  ● ЗаписыватьТолькоНовые – записывать только новые объекты.  ● Записывать – записывать новые и модифицированные объекты.  ● Проводить – проводить документы.  Например:  Команда.РежимЗаписи = "НеЗаписывать";  Перед записью и проведением у пользователя запрашивается подтверждение. Значение по умолчанию: Записывать |
| ТребуетсяРаботаСФайлами (необязательный) | Булево | Если Истина, то в веб-клиенте перед выполнением команды предлагается установить расширение работы с файлами |
| Настройки обработчика: | | |
| Менеджер (необязательный) | Строка | Полное имя объекта метаданных, отвечающего за выполнение команды. Заполняется автоматически полным именем объекта, в модуле менеджера которого добавлена команда |
| ИмяФормы (обязательный, если не указан Обработчик) | Строка | Имя формы, которую требуется получить для выполнения команды. Если Обработчик не указан, то у формы вызывается метод Открыть |
| ПараметрыФормы (необязательный) | Структура, Неопределено | Параметры формы, указанной в ИмяФормы |
| Обработчик (обязательный, если не указано ИмяФормы) | Строка | Имя процедуры, обрабатывающей основное действие команды.  Пример № 1 - обработчик размещен в общем модуле:  Команда.Обработчик = "ПродажиКлиент.ВвестиСчетФактуру";  Пример № 2 - обработчик размещен в модуле формы или менеджера:  Команда.Обработчик = "ЗаполнитьТТН";  Если ИмяФормы заполнено, то в модуле указанной формы ожидается клиентская процедура по шаблону:  &НаКлиенте  Процедура <ИмяПроцедуры>(<ИмяПараметраКоманды>, ПараметрыВыполнения) Экспорт  // Код обработчика команды.  КонецПроцедуры  Если ИмяФормы не заполнено, то в модуле менеджера объекта, указанного в Менеджер, ожидается серверная процедура по шаблону:  Процедура <ИмяПроцедуры>(<ИмяПараметраКоманды>, ПараметрыВыполнения) Экспорт  // Код обработчика команды.  КонецПроцедуры  Имя 1-го параметра обработчика команды <ИмяПараметраКоманды> рекомендуется задавать в соответствии с типами объектов, для которых предназначена команда. Также следует учитывать, что тип этого параметра зависит от настройки МножественныйВыбор. Если МножественныйВыбор = Истина, то передается массив ссылок, в противном случае передается ссылка. Например, если команда предназначена для заполнения документов Счет на оплату и МножественныйВыбор включен, то параметр можно называть МассивСчетовНаОплату или СчетаНаОплату. Если МножественныйВыбор отключен, то параметр можно назвать СчетНаОплату или СсылкаСчетаНаОплату.  2-й параметр обработчика команды ПараметрыВыполнения имеет тип Структура со следующими полями:  ● ОписаниеКоманды - Структура - Описание команды (ключи соответствуют колонкам этой таблицы).  ● Идентификатор - Строка - Идентификатор команды.  ● Представление - Строка - Представление команды в форме.  ● ДополнительныеПараметры - Неопределено, ФиксированнаяСтруктура - Дополнительные параметры команды.  ● Форма - УправляемаяФорма - Форма, из которой вызвана команда.  ● ЭтоФормаОбъекта - Булево - Истина, если команда вызвана из формы объекта.  ● Источник - ТаблицаФормы, ДанныеФормыСтруктура - Объект или список формы с полем Ссылка |
| ДополнительныеПараметры (необязательный) | Структура, Неопределено | Дополнительные параметры, которые могут быть считаны в обработчике команды |

Примеры команд и их обработчиков см. в обработке \_ДемоПодключаемыеКомандыЗаполнениеКонтрагентов расширения \_ДемоПодключаемыеКоманды демонстрационной конфигурации.

**Настройка обмена данными**

Для настройки обмена данными никаких действий не требуется, так как подсистема не предоставляет собственных данных.